MODULE Init;

​

IMPORT Draw, Strings, Forms;

​

CONST

 rows = 40; cols = 50; size = 10; bH = 44; 

 width = cols * size + 1; height = rows * size + bH + 10;

 bY = height - bH - 1;

 diffTitle = "diffusion coefficient";

​

VAR

 run: BOOLEAN; dt, dx, t: REAL; sourceX, sourceY: INTEGER;

 a, aNew: ARRAY cols, rows OF REAL;

 kD: Forms.Slider; pressed: BOOLEAN;

​

PROCEDURE SetSource;

VAR x, y: INTEGER;

BEGIN

  x := (Draw.mouseX - 3) DIV size;  y := (Draw.mouseY - 3) DIV size;

  IF (x >= 0) & (x < cols) & (y >= 0) & (y < rows) THEN

   sourceX := x; sourceY := y

  END;

END SetSource;

​

PROCEDURE Pressed;

BEGIN pressed := TRUE; SetSource

END Pressed;

​

PROCEDURE Released;

BEGIN pressed := FALSE

END Released;

​

PROCEDURE Step;

VAR i, j, t1, t2: INTEGER; tmp, pp: REAL; 

BEGIN

 IF pressed THEN SetSource END;

 IF (sourceX # -1) & (sourceY # -1) THEN

  a[sourceX, sourceY] := a[sourceX, sourceY] + 50.

 END;

 tmp := kD.value * dt / (dx * dx);

 FOR i := 0 TO cols - 1 DO

  FOR j := 0 TO rows - 1 DO

   pp := 0.0;

   IF i > 0 THEN pp := pp + (a[i - 1, j] - a[i, j]) END;

   IF i < cols - 1 THEN pp := pp + (a[i + 1, j] - a[i, j]) END;

   IF j > 0 THEN pp := pp + (a[i, j - 1] - a[i, j]) END;

   IF j < rows - 1 THEN pp := pp + (a[i, j + 1] - a[i, j]) END;

   aNew[i, j] := a[i, j] + tmp * pp

  END

 END;

 a := aNew;

 t := t + dt

END Step;

​

PROCEDURE Restore;

VAR i, j, x, y, color: INTEGER; str: ARRAY 32 OF CHAR; sum: REAL;

BEGIN

 Step;

 (* draw *)

 Draw.SetBackgroundRGB(255, 255, 255);

 Draw.NoStroke; Draw.Fill(0FF4444FFH);

 FOR i := 0 TO cols - 1 DO

  FOR j := 0 TO rows - 1 DO

   IF a[i, j] > 1.0 THEN

    color := FLOOR(a[i, j] * 2.0);

    IF color > 255 THEN color := 255 END;

    Draw.FillRGB(255 - color, 255, 255 - color);

    Draw.Recti(i * size, j * size, size, size)

   END

  END

 END;

 Draw.NoFill; Draw.StrokeRGB(0,0,0); Draw.StrokeWidth(1);

 Draw.Recti(1, 1, cols*size-2, rows*size-2);

 sum := 0.0;

 FOR i := 0 TO cols - 1 DO

  FOR j := 0 TO rows - 1 DO

   sum := sum + a[i, j]

  END

 END;

 (* draw time and total substrate *)

 Strings.RealToStringFixed(sum, str, 1);

 Draw.FillRGB(0, 0, 0); Draw.NoStroke;

 Draw.Stringi(str, width - 100, bY + bH - 6, 16);

 Strings.RealToStringFixed(t, str, 1);

 Strings.Append(" s", str);

 Draw.Stringi(str, 10, bY + bH - 6, 16);

END Restore;

​

PROCEDURE Setup;

BEGIN

 Draw.SetSize(width, height);

 Draw.SetFrameRate(20);

 kD := Forms.NewSlider(100, bY, 260, 44, diffTitle, 0., 3.,  0.1, NIL);

 Forms.SetReal(kD, 1.5);

END Setup;

​

BEGIN

 dx := 1.0; dt := 0.05; t := 0.0;

 run := FALSE; sourceX := -1; sourceY := -1;

 (* init drawing *)

 Draw.SetSetupProc(Setup);

 Draw.SetDrawProc(Restore);

 Draw.SetPressedProc(Pressed);

 Draw.SetReleasedProc(Released);

 Draw.SetOutProc(Released);

 Draw.Start

END Init.